本章主题：

1. 什么是函数栈帧？

2. 理解函数栈帧能解决什么问题

3. 函数栈帧的创建和销毁解析

一、什么是函数栈帧

C语言是一门结构化语言，是以函数为基本单位的。那函数是如何调用的？函数的返回值又是如何带回的？函数参数是如何传递的？这些问题都和函数栈帧有关系。

函数栈帧（stack frame）就是函数调用过程中程序的调用栈（call stack）所开辟的空间，这些空间是用来存放：

（1）函数参数和函数返回值

（2）临时变量（包括函数的非静态的局部变量以及编译器自动产生的其他临时变量）

（3）保存上下文消息（包括在函数调用前后需要保持不变的寄存器）

二、理解函数栈帧能解决什么问题呢？

理解函数栈帧有什么用呢？

答：只要理解了函数栈帧的创建和销毁，以下问题就能很好的理解：

（1）局部变量是如何创建的？

（2）为什么局部变量不初始化内容是随机的？

（3）函数调用时参数是如何传递的？传参的顺序是怎样的？

（4）形参是怎么访问的？

（5）函数的返回值是如何带回的？

让我们一起走进函数栈帧的创建和销毁的过程中。

三、函数栈帧的创建和销毁解析

1、什么是栈？

栈（stack）是现代计算机程序里最为重要的概念之一，几乎每一个程序都使用了栈，没有栈就没有函数，没有局部变量，也就没有我们如今看到的所有的计算机语言。

在经典的计算机科学中，栈被定义为一种特殊的容器，用户可以将数据压入栈中（入栈，push），也可以将已经压入栈的数据弹出（出栈，pop），但是栈这个容器必须遵守一条规则：先入栈的数据后出栈（first in last out，FIFO）。就像叠成一叠的书，先叠上去的书在最下面，因此要最后才能取出。

在计算机系统中，栈则是一个具有以上属性的动态内存区域。程序可以将数据压入栈中，也可以将数据从栈顶弹出。压栈操作使得栈增大，而弹出操作使得栈减小。

在经典的操作系统中，栈总是向下增长的（由高地址向低地址）。

2、认识相关寄存器和汇编指令

相关寄存器：

eax：通用寄存器，保留临时数据，常用于返回值。

ebx：通用寄存器，保留临时数据

ebp：栈底寄存器

esp：栈顶寄存器

eip：指令寄存器，保存当前指令的下一条指令的地址

相关汇编命名：

mov：数据转移指令

push：数据入栈，同时esp栈顶寄存器也要发生改变

pop：数据弹出至指定位置，同时esp栈顶寄存器也要发生改变

sub：减法命令

add：加法命令

call：函数调用，1. 压入返回地址，2. 转入目标函数

jump：通过修改eip，转入目标函数，进行调用

ret：恢复返回地址，压入eip，类似pop eip命令

3、解析函数栈帧的创建和销毁

（1）预备知识

首先我们达成一些预备知识才能有效的帮助我们理解，函数栈帧的创建和销毁。

1、每一次函数调用，都要为本次函数调用开辟空间，就是函数栈帧的空间。

2、这块空间的维护是使用2个寄存器：esp和ebp，ebp记录的是栈底的地址，esp记录的是栈顶的地址。

如图所示：

3、函数栈帧的创建和销毁过程，在不同编译器上实现的方法大同小异，注重理解，本次演示我就以VS2019为例。

（2）函数的调用堆栈

代码演示：为了方便观察，把代码尽量详细。

#include<stdio.h>int Add(int x, int y)
{int sum = 0;sum = x + y;return sum;
}int main()
{int a = 2;int b = 3;int ret = 0;ret = Add(a, b);printf("%d\n", ret);return 0;
}

F10调试起来，调试进入Add函数后，我们观察堆栈（右击勾选【显示外部代码】），如下图：

函数调用堆栈是反馈函数调用的逻辑，如图我们可以观察到，main函数也是被其他函数调用的，在main函数调用之前，是由invoke_main函数来调用main函数的。在invoke_main函数之前的函数调用我们就暂时不考虑了。

我们可以确定。invoke_main函数会有自己的栈帧，main函数和Add函数也会有自己的栈帧，每一个函数栈帧都有自己的ebp和esp来维护栈帧空间。

（3）那接下来我们从main函数的栈帧创建开始讲解：

步骤一：准备环境

为了让我们研究函数栈帧的过程足够清晰，不要太多干扰，我们可以修改选项，让汇编代码中排除一些编译器附加的代码：

过程1：

过程2：

步骤二：转到反汇编

调试到main函数开始执行的第一行，右击鼠标转到反汇编（再右击将显示名去掉——显示地址）。

注：VS编译器每次调试都会为程序重新分配内存，每一次调试略有小异。

int main()
{

//函数栈帧的创建
00C71820 push ebp
00C71821 mov ebp,esp
00C71823 sub esp,0E4h
00C71829 push ebx
00C7182A push esi
00C7182B push edi
00C7182C lea edi,[ebp-24h]
00C7182F mov ecx,9
00C71834 mov eax,0CCCCCCCCh
00C71839 rep stos dword ptr es:[edi]

//main函数中的核心代码
   int a = 2;
00C7183B mov dword ptr [ebp-8],2
   int b = 3;
00C71842 mov dword ptr [ebp-14h],3
   int ret = 0;
00C71849 mov dword ptr [ebp-20h],0
   ret = Add(a, b);
00C71850 mov eax,dword ptr [ebp-14h]
00C71853 push eax
00C71854 mov ecx,dword ptr [ebp-8]
00C71857 push ecx
00C71858 call 00C710B4
00C7185D add esp,8
00C71860 mov dword ptr [ebp-20h],eax
   printf("%d\n", ret);
00C71863 mov eax,dword ptr [ebp-20h]
00C71866 push eax
00C71867 push 0C77B30h
00C7186C call 00C710D2
00C71871 add esp,8
   return 0;
00C71874 xor eax,eax
}

main函数栈帧的创建

这里我们看到main函数转化的汇编代码如上所示。

接下来我们就一行一行拆解汇编代码：

int main()
{
00C71820 push ebp //push 压栈：把ebp寄存器中的值压栈，此时的ebp中存放的是invoke_main函数栈帧的ebp

00C71821 mov ebp,esp //mov指令会把esp的值存放到ebp中，相当于产生了main函数的ebp，这个值就是invoke_main函数栈帧的esp
00C71823 sub esp,0E4h //sub会让esp中的地址减去一个16进制数字0xe4,产生新的

esp，此时的esp是main函数栈帧的esp，此时结合上一条指令的ebp和当前的esp，ebp和esp之间维护了一个块栈空间，这块栈空间就是为main函数开辟的，就是main函数的栈帧空间，这一段空间中将存储main函数中的局部变量，临时数据。

00C71829 push ebx //将寄存器ebx的值压栈，esp-4
00C7182A push esi //将寄存器esi的值压栈，esp-4
00C7182B push edi //将寄存器edi的值压栈，esp-4

//上面3条指令保存了3个寄存器的值在栈区，这3个寄存器的在函数随后执行中可能会被修改，所以先保存寄存器原来的值，以便在退出函数时恢复。

//下面的代码是在初始化main函数的栈帧空间

00C7182C lea edi,[ebp-24h] //1.把ebp-24h的地址，放到edi中
00C7182F mov ecx,9 //2.把9放到ecx中
00C71834 mov eax,0CCCCCCCCh //3.把0xcccccccc放在eax中
00C71839 rep stos dword ptr es:[edi] //将从ebp-24h到ebp这段的每个字节都初始化为0XCC

上面这段代码最后4句，等价于下面的伪代码：

edi = ebp - 0x24 ;

ecx = 9 ;

eax = 0xCCCCCCCC ;

for (; ecx = 0 ; -- ecx , edi += 4 )

{

* ( int* ) edi = eax ;

}

接下来我们再分析main函数中的核心代码：

int a = 2;
00C7183B mov dword ptr [ebp-8],2 //将2存储到ebp-8的地址处，ebp-8的位置其实就

是a变量

   int b = 3;
00C71842 mov dword ptr [ebp-14h],3 //将3存储到ebp-14h的地址处，ebp-14h的位置

其实是b变量

   int ret = 0;
00C71849 mov dword ptr [ebp-20h],0 //将0存储到ebp-20h的地址处，ebp-20h的位

置其实是ret变量

//以上汇编代码表示的变量a,b,ret的创建和初始化，这就是局部的变量的创建和初始化

//其实是局部变量的创建时在局部变量所在函数的栈帧空间中创建的

//调用Add函数

   ret = Add(a, b);

//调用Add函数时的传参

//其实传参就是把参数push到栈帧空间中

00C71850 mov eax,dword ptr [ebp-14h] //传递b，将ebp-14h处放的5放在eax寄存器

中

00C71853 push eax //将eax的值压栈，esp-4
00C71854 mov ecx,dword ptr [ebp-8] //传递a，将ebp-8处放的3放在ecx寄存器中
00C71857 push ecx //将ecx的值压栈，esp-4

//跳转调用函数

00C71858 call 00C710B4
00C7185D add esp,8
00C71860 mov dword ptr [ebp-20h],eax
call指令是要执行函数调用逻辑的，1.压入返回地址（在执行call指令之前先会把call指令的下一条指令的地址进行压栈操作，这个操作是为了解决当函数调用结束后要回到call指令的下一条指令的地方，继续往后执行。） 2.转入目标函数

当我们跳转到Add函数，就要开始观察Add函数的反汇编代码了：

（4）Add函数栈帧的创建：

int Add(int x, int y)
{
00C71760 push ebp //push压栈：将main函数栈帧的ebp保存，esp-4
00C71761 mov ebp,esp //将main函数的esp赋值给新的的ebp，ebp现在是Add的ebp
00C71763 sub esp,0CCh //将esp-0xcc，求出Add函数的esp
00C71769 push ebx //将ebx的压栈，esp-4
00C7176A push esi //将esi的值压栈，esp-4
00C7176B push edi //将edi的值压栈，esp-4
   int sum = 0;
00C7176C mov dword ptr [ebp-8],0 //将0放在ebp-8的地址处，就是创建sum
   sum = x + y;
00C71773 mov eax,dword ptr [ebp+8] //将ebp+8地址处的值赋值给eax
00C71776 add eax,dword ptr [ebp+0Ch] //将ebp+12地址处的值加到eax中
00C71779 mov dword ptr [ebp-8],eax //将eax的值保存到ebp-8的地址处，就是放到z
   return sum;
00C7177C mov eax,dword ptr [ebp-8] //将ebp-8的值赋值再eax中，其实就是把z的值存储到eax寄存器中，这里是想通过eax寄存器带回计算的结果，做函数的返回值。
}
00C7177F pop edi
00C71780 pop esi
00C71781 pop ebx
00C71782 mov esp,ebp
00C71784 pop ebp
00C71785 ret

代码执行到Add函数的时候，就要开始创建Add函数的栈帧空间了。

在Add函数中创建栈帧的方法和在main函数中是相似的，在栈帧空间的大小上略有差异而已。

1、将main函数的ebp压栈

2、计算新的ebp和esp

3、将ebx，esi，edi寄存器的值压栈保存

4、计算求和，在计算求和的时候，我们是通过ebp中的地址进行偏移访问到函数调用前压栈进去的参数，这就是形参访问。

5、返回值放在eax寄存器中准备带回（调用结束后，栈帧销毁所以把值放在寄存器中，寄存器是集成到CPU上的）。

如图我们可以清楚的知道函数的传参过程，以及函数在进行值传递调用的时候，形参其实就是实参的一份拷贝。对形参的修改不会影响实参。

（5）函数栈帧的销毁

当函数调用要结束的时候，前面创建的函数栈帧也开始销毁。

那具体是怎么销毁的呢？我们看一下反汇编代码。

Add函数栈帧的销毁：

00C7177F pop edi //在栈顶弹出一个值，存放到edi中，esp+4
00C71780 pop esi //在栈顶弹出一个值，存放到esi中，esp+4
00C71781 pop ebx //在栈顶弹出一个值，存放到ebx中，esp+4
00C71782 mov esp,ebp //将Add函数的ebp的值赋值给esp，相当于回收了Add函数的栈帧空间
00C71784 pop ebp //弹出弹出栈顶的值，存放到ebp中，栈顶此时的值恰好就是main函数的ebp，esp+4此时恢复了main函数的栈帧维护，esp指向main函数栈帧的栈顶，ebp指向main函数栈帧的栈顶。
00C71785 ret //ret指令的执行，首先是从栈顶弹出一个值，此时栈顶的值就是call指令下一条指令的地址，此时esp+4，然后直接跳转到call指令下一条指令的地址处，继续往下执行。

回到call指令的下一条指令的地方：（回到main函数）

00C7185D add esp,8 //esp+8，相当于跳过了main函数中压栈的a与b的形参
00C71860 mov dword ptr [ebp-20h],eax //将eax中值，存储到ebp-0x20的地址处，其实就是存储到main函数中的ret变量中，而此时eax中就是Add函数中的返回值，可以看出来，本次函数的返回值是由eax寄存器带回来的。程序是在函数调用返回之后，去eax中读取返回值的。

printf("%d\n", ret);
00C71863 mov eax,dword ptr [ebp-20h]
00C71866 push eax
00C71867 push 0C77B30h
00C7186C call 00C710D2
00C71871 add esp,8